制作WinPE3.0的方法

:: 本程序從 WINDOWS 7 安裝光盤(pán)中提取并生成純凈的 Windows 7 PE 映像。

:: 請(qǐng)將 WINDOWS 7 安裝光盤(pán)放入光驅(qū) J:，也可以將安裝映像加載到虛擬光驅(qū) J: 。

:: 請(qǐng)預(yù)先將 imagex.exe 文件拷貝至 %SYSTEMDRIVE% 根目錄。

rem @echo off

setlocal enabledelayedexpansion

color 2e

title 從 WINDOWS 7 安裝光盤(pán)中提取 WinPE3.0

@echo.

@echo 本程序從 WINDOWS 7 安裝光盤(pán)中提取并生成純凈的 Windows 7 PE 映像。

@echo.

@echo 請(qǐng)將 WINDOWS 7 安裝光盤(pán)放入光驅(qū) J:，支持將映像加載到虛擬光驅(qū) J: 。

@echo.

@echo 請(qǐng)預(yù)先將 imagex.exe 文件拷貝至 %SYSTEMDRIVE% 根目錄。

@echo.

@echo Code by Bootp.Lu

@echo.

pause

:: 一、準(zhǔn)備

set cdrom_disk=J:

:: 如光驅(qū)盤(pán)符不是 J:，請(qǐng)按照實(shí)際情況修改上面一行內(nèi)容。

md %SYSTEMDRIVE%\_temp_mount

md %SYSTEMDRIVE%\_temp_wim

md %SYSTEMDRIVE%\_temp_wim\boot

md %SYSTEMDRIVE%\_temp_wim\efi

md %SYSTEMDRIVE%\_temp_wim\sources

:: 二、用 WINDOWS 7 安裝光盤(pán)中 %cdrom_disk%\sources\boot.wim 提取 Windows 7 PE 映像。

:: 拷貝原文件和目錄。

copy %cdrom_disk%\sources\boot.wim %SYSTEMDRIVE%\_temp_wim\boot_c.wim

copy %cdrom_disk%\bootmgr %SYSTEMDRIVE%\_temp_wim

xcopy %cdrom_disk%\boot\*.* %SYSTEMDRIVE%\_temp_wim\boot /i /e /c /f /h /x /y

xcopy %cdrom_disk%\efi\*.* %SYSTEMDRIVE%\_temp_wim\efi /i /e /c /f /h /x /y

:: 拷貝%cdrom_disk%\sources\dism.exe，以備后續(xù)步驟使用。

copy %cdrom_disk%\sources\dism.exe %SYSTEMDRIVE%\

:: 從原鏡像中提取純凈的 Windows 7 PE 映像。

%SYSTEMDRIVE%\imagex /export %SYSTEMDRIVE%\_temp_wim\boot_c.wim 1 %SYSTEMDRIVE%\_temp_wim\sources\boot.wim

del /f /q %SYSTEMDRIVE%\_temp_wim\boot_c.wim

:: 三、修改映像，除掉冗余文件，刪除原有的啟動(dòng)參數(shù)，輸入新的啟動(dòng)參數(shù)。

:: 解開(kāi)映像供進(jìn)一步修改。

%SYSTEMDRIVE%\imagex /mountrw %SYSTEMDRIVE%\_temp_wim\sources\boot.wim 1 %SYSTEMDRIVE%\_temp_mount

:: 修改映像

if exist %SYSTEMDRIVE%\_temp_mount\setup.exe del /q /f %SYSTEMDRIVE%\_temp_mount\setup.exe

if exist %SYSTEMDRIVE%\_temp_mount\Windows\System32\winpeshl.ini del /f /q %SYSTEMDRIVE%\_temp_mount\Windows\System32\winpeshl.ini

:: 下面三行，定義PE和用戶(hù)自己的程序的接口，如無(wú)，可在此三行刪除。

REM attrib -r -h -s %SYSTEMDRIVE%\_temp_mount\Windows\System32\startnet.cmd

REM echo. >>%SYSTEMDRIVE%\_temp_mount\Windows\System32\startnet.cmd

REM echo CALL C:\<MyPath>\MyProgram.bat >>%SYSTEMDRIVE%\_temp_mount\Windows\System32\startnet.cmd

:: 清理無(wú)用的臨時(shí)工作目錄

rd /s /q %SYSTEMDRIVE%\_temp_mount\sources

:: 添加ImageX等工具。

copy %SYSTEMDRIVE%\imagex.exe %SYSTEMDRIVE%\_temp_mount\Windows\System32\

:: 重新封裝，保存修改后的映像。

%SYSTEMDRIVE%\imagex /unmount /commit %SYSTEMDRIVE%\_temp_mount

:: 四、定義和部署映像

:: 查看映像索引

%SYSTEMDRIVE%\dism /get-wiminfo /wimfile:%SYSTEMDRIVE%\_temp_wim\sources\boot.wim

:: 查看映像索引“1”的詳細(xì)情況

%SYSTEMDRIVE%\dism /get-wiminfo /wimfile:%SYSTEMDRIVE%\_temp_wim\sources\boot.wim /index:1

:: 使用 DISM 將基本 Windows PE 映像裝入 Mount 目錄。完成后，可以看到mount目錄下已經(jīng)有了“解壓”文件。

%SYSTEMDRIVE%\dism /Mount-Wim /Wimfile:%SYSTEMDRIVE%\_temp_wim\sources\boot.wim /index:1 /MountDir:%SYSTEMDRIVE%\_temp_mount

:: 使用帶有 /GetPackages 選項(xiàng)的 DISM 命令查看當(dāng)前映像中的所有程序包，驗(yàn)證這些程序包是否已安裝。

rem %SYSTEMDRIVE%\dism /image:%SYSTEMDRIVE%\_temp_mount /Get-Packages

:: 使用具有以下語(yǔ)法的 /Set-AllIntl 選項(xiàng)設(shè)置默認(rèn)語(yǔ)言。如果安裝光盤(pán)是中文版WINDOWS 7，此行可忽略。

rem %SYSTEMDRIVE%\dism /image:%SYSTEMDRIVE%\_temp_mount /Set-AllIntl:zh-cn

:: 使用 /Get-Intl 選項(xiàng)驗(yàn)證語(yǔ)言設(shè)置。

rem %SYSTEMDRIVE%\dism /image:%SYSTEMDRIVE%\_temp_mount /Get-Intl

:: 修改暫存空間。該命令最后的256是代表256M的意思，默認(rèn)WINPE只會(huì)分配32M暫存內(nèi)存，有點(diǎn)小。

%SYSTEMDRIVE%\dism /image:%SYSTEMDRIVE%\_temp_mount /Set-ScratchSpace:256

:: 設(shè)定enable-profiling

%SYSTEMDRIVE%\dism /image:%SYSTEMDRIVE%\_temp_mount /enable-profiling

:: 設(shè)定磁盤(pán)上 Windows PE 映像的位置Set-TargetPath

%SYSTEMDRIVE%\dism /image:%SYSTEMDRIVE%\_temp_mount /Set-TargetPath:C:\

:: 提交對(duì)映像的更改。在此步驟中，將 DISM /unmount 選項(xiàng)和 /commit 選項(xiàng)一起使用提交對(duì)原始映像的更改。

%SYSTEMDRIVE%\dism /unmount-Wim /MountDir:%SYSTEMDRIVE%\_temp_mount /Commit

:: 執(zhí)行完后，mount目錄會(huì)被自動(dòng)清空，相當(dāng)于又“壓縮”回去，此時(shí)可刪除 _temp_mount 目錄。

rd /s /q %SYSTEMDRIVE%\_temp_mount

@echo.

@echo 預(yù)安裝環(huán)境 Windows 7 PE 配置完成，文件保存在 %SYSTEMDRIVE%\_temp_wim 中。

@echo.

@echo 用一般的光盤(pán)刻錄工具，就可以刻錄成 Windows 7 PE 光盤(pán)備用。

:: 五、創(chuàng)建 Windows 7 PE 的可引導(dǎo)光盤(pán)

:: 創(chuàng)建可引導(dǎo) CD-ROM。將 Windows PE RAM 盤(pán)放到 CD-ROM 上，需要使用 Oscdimg 工具創(chuàng)建 .iso 文件。

:: 若要?jiǎng)h除引導(dǎo)期間的“按任意鍵從 CD 啟動(dòng)……”提示，請(qǐng)刪除 boot 文件夾下的 bootfix.bin 文件。

:: 格式如下：

:: oscdimg -n -m -o -b%SYSTEMDRIVE%\etfsboot.com %SYSTEMDRIVE%\_temp_wim %SYSTEMDRIVE%\winpe_x86_bootp.iso

rem copy %SYSTEMDRIVE%\_temp_wim\boot\etfsboot.com %SYSTEMDRIVE%\

rem %SYSTEMDRIVE%\oscdimg -n -m -o -b%SYSTEMDRIVE%\etfsboot.com %SYSTEMDRIVE%\_temp_wim %SYSTEMDRIVE%\winpe_x86_bootp.iso

:: 此處跳過(guò) ISO 文件的生成。如不想跳過(guò)，除掉上面兩行代碼前的 rem 即可。

:: ISO映像主要是刻寫(xiě) WinPE 光盤(pán)用，如需生成ISO文件，需要微軟的 oscdimg.exe 小文件。

:: 六、清理

rem del /f /q %SYSTEMDRIVE%\etfsboot.com

del /f /q %SYSTEMDRIVE%\dism.exe

@echo.

@echo.

@echo 純凈的原生態(tài) Windows 7 PE 3.0 制作完畢。 Code by Bootp.Lu

@echo --------------------------------------------------------------

@echo.

@echo.

@echo.

@echo 后續(xù)步驟可以把 Windows 7 PE 安裝到系統(tǒng)盤(pán) C: 上，并以硬盤(pán)方式啟動(dòng)預(yù)安裝環(huán)境。

@echo.

@echo.

pause

(責(zé)任編輯：大白菜官網(wǎng))